streams.clj

Branches > main > 5080ff4 > files / src / net / bowmap / transport / streams.clj

(ns net.bowmap.transport.streams
  "Functions for reading and writing frames from input and output streams"
  (:require
   [net.bowmap.protocol.packet.types :as t])
  (:import
   [io.netty.buffer ByteBuf Unpooled]
   [java.io
    EOFException
    IOException
    InputStream
    OutputStream]))

(defn read-byte!!
  "Blocks and returns an unsigned byte from 'input-stream', or throws if EOF is reached"
  [input-stream]
  (let [x (InputStream/.read input-stream)]
    (if (= -1 x)
      (throw (EOFException. "EOF while reading from InputStream"))
      x)))

(defn read-varint!!
  "Blocks and returns a varint from 'input-stream', or throws if one cannot be read"
  [input-stream]
  (loop [num-read 0
         result 0]
    (if (>= num-read t/max-varint-size)
      (throw (IOException. "VarInt too long"))
      (let [b (read-byte!! input-stream)
            result' (bit-or result (bit-shift-left (bit-and b 0x7F) (* 7 num-read)))]
        (if (zero? (bit-and b 0x80))
          result'
          (recur (inc num-read) result'))))))

(defn read-frame!!
  "Blocks and reads a frame from 'input-stream'. Throws if one cannot be read"
  [input-stream]
  (let [len (read-varint!! input-stream)
        arr (byte-array len)]
    (loop [offset 0]
      (when (< offset len)
        (let [r (InputStream/.read input-stream arr offset (- len offset))]
          (if (= r -1)
            (throw (EOFException. "EOF while reading frame"))
            (recur (+ offset r))))))
    (Unpooled/wrappedBuffer arr)))

(defn write-frame!!
  "Blocks and writes a frame to 'output-stream'. Throws if it cannot be written."
  [frame output-stream]
  (let [len (ByteBuf/.readableBytes frame)
        arr (byte-array len)]
    (ByteBuf/.readBytes frame arr)
    (OutputStream/.write output-stream arr)
    (OutputStream/.flush output-stream)))